Projecten - Reactietest

Test uw eigen reactiesnelheid. Als de LED groen brandt, is de test klaar om te starten. Druk de drukknop in laat hem weer los en de LED zal geel oplichten. Als de LED uitgaat, wordt het spannend. Wacht tot de LED blauw gaat branden en druk dan zo snel mogelijk op de drukknop. De LED zal groen knipperen en in het display verschijnt de reactietijd, tenzij de drukknop is ingedrukt voordat de blauwe LED aanging. Dan knippert de LED rood. Daarna gaat de groene LED weer branden en is de test weer klaar voor gebruik.

Heeft u niet de beschikking over een driekleuren LED, dan kunt u natuurlijk een rode, groene en blauwe LED gebruiken. In plaats van een gele kleur zullen dan de rode en de groene led gaan branden.

Schakeling

Onderdelen

Component	Type	Aantal
D1, D2, D3	Driekleuren LED	1
R1, R2, R3	470Ω	3
R4, R5, R6, R7	10kΩ	4
T1, T2, T3	BC549C	3
S1	Drukschakelaar Zwart	1
Optioneel
	LCD Display	1

Sketches

In beide onderstaande sketches maken we gebruik van een eenvoudige drukschakelaar met alleen een maakcontact. Om het denderen (zie de sectie over gebruik van drukschakelaars) te ondervangen, wachten we telkens na het indrukken van de schakelaar 100 ms. Daarbij gaan we ervan uit dat het denderen niet langer dan die 100 ms zal duren. Onderstaande sketch geeft de code voor het gebruik van de reactietijdmeter in combinatie met een LCD display. Meer informatie over het aansluiten van een LCD display is te vinden in de sectie over gegevensuitvoer. Om de kleuren te kunnen mengen, zijn de LED's aangesloten op outputs met pulsbreedtemodulatie (PWM). In dit geval zijn dat de pinnen 9, 10 en 11.

//Sketch voor het testen van reactiesnelheid
//
//Aansluitingen
//  - Schakelaar tussen 5V en Arduino digitale pin 13
//  - Een weerstand van 10 kΩ tussen Arduino digitale pin 13 en GND
//  - 3-Kleuren LED:
//    - Common anode aan 5V
//    - 470 Ω weerstanden tussen:
//      - Kathode Rood en collector van T1
//      - Kathode Groen en collector van T2
//      - Kathode Blauw en collector van T3
//    - 10 kΩ weerstanden tussen:
//      - Arduino digitale pin  9 en basis van T1
//      - Arduino digitale pin 10 en basis van T2
//      - Arduino digitale pin 11 en basis van T3
//    - Emitter van T1 aan GND
//    - Emitter van T2 aan GND
//    - Emitter van T3 aan GND

//  - LCD display
//    - Pin  1: aan de GND van de Arduino
//    - Pin  2: aan +5V
//    - Pin  3: aan slede van 10k potentiometer tussen 5V en GND
//    - Pin  4: aan digitale pin 2 van de Arduino
//    - Pin  5: aan de GND van de Arduino
//    - Pin  6: aan digitale pin 3 van de Arduino
//    - Pin 11: aan digitale pin 4 van de Arduino
//    - Pin 12: aan digitale pin 5 van de Arduino
//    - Pin 13: aan digitale pin 6 van de Arduino
//    - Pin 14: aan digitale pin 7 van de Arduino

#include <LiquidCrystal.h>

const int  RS  =  2;
const int  E   =  3;
const int  D4  =  4;
const int  D5  =  5;
const int  D6  =  6;
const int  D7  =  7;

LiquidCrystal lcd(RS, E, D4, D5, D6, D7);

const int Rood   =  9; //PWM pin
const int Groen  = 10; //PWM pin
const int Blauw  = 11; //PWM pin
const int Switch = 13;

const int Knipperaantal = 5;
const int Knippervertraging = 250;

void setup(void){
  pinMode(Switch, INPUT);
  pinMode(Rood,   OUTPUT);
  pinMode(Groen,  OUTPUT);
  pinMode(Blauw,  OUTPUT);
  //Initialiseer de random generator
  randomSeed(analogRead(0));
  lcd.begin(16, 2);
  lcd.display();
  lcd.clear();
}

void Kleur(int rood, int groen, int blauw){
  analogWrite(Rood,  rood);
  analogWrite(Groen, groen);
  analogWrite(Blauw, blauw);
}

void Knipper(int rood, int groen, int blauw, int aantal, int vertraging){
  int  Teller;
  
  for (Teller = 0; Teller < aantal; Teller++){
    Kleur(rood, groen, blauw);
    delay(vertraging);
    Kleur(0, 0, 0);
    delay(vertraging);
  }
}

void loop(void){
  bool Cheat;
  int  Wachttijd, WachtStart, VerlopenTijd;
  int  Starttijd, Eindtijd;
  char Reactietijdtekst[17];
  
  //Zet het licht op groen om aan te geven dat de test kan starten
  Kleur(0, 255, 0);
  //Wacht tot de schakelaar is losgelaten
  while (digitalRead(Switch) == HIGH);
  //Gebruik een pseudo ontdendering door 50 ms te wachten
  delay(100);
  //Wacht tot de schakelaar is ingedrukt  
  while (digitalRead(Switch) == LOW);
  //Gebruik een pseudo ontdendering door 50 ms te wachten
  delay(100);
  //Wacht tot de schakelaar is losgelaten
  while (digitalRead(Switch) == HIGH);
  
  //Zet het licht op geel
  Kleur(255, 140, 0);
  delay(1000);
  Kleur(0, 0, 0);
  //Genereer wachttijd tussen 2 en 5 seconden
  Wachttijd = random(2000, 5000);
  //Zet starttijd op basis van interne klok
  WachtStart = millis();
  Cheat = false;
  do{
    if (digitalRead(Switch) == HIGH){
      Cheat = true;
      break;
    }
    VerlopenTijd = millis() - WachtStart;
  } while (VerlopenTijd < Wachttijd);
  //Set het licht op blauw
  Kleur(0, 0, 255);
  Starttijd = millis();
  //Wacht tot de schakelaar wordt ingedrukt
  do{
  } while (digitalRead(Switch) == LOW);
  Eindtijd = millis();
  if (Cheat){
    Knipper(255, 0, 0, Knipperaantal, Knippervertraging);
  } else {
    sprintf(Reactietijdtekst, "%d ms", Eindtijd - Starttijd);
    lcd.clear();
    lcd.print(Reactietijdtekst);
    Knipper(0, 255, 0, Knipperaantal, Knippervertraging);
  }
}

Als u niet de beschikking heeft over een LCD display, kunt u de uitvoer ook via de Seriële Monitor. Meer informatie daarover is te vinden in de sectie over gegevensuitvoer.

//Sketch voor het testen van reactiesnelheid
//
//Aansluitingen
//  - Schakelaar tussen 5V en Arduino digitale pin 13
//  - Een weerstand van 10 kΩ tussen Arduino digitale pin 13 en GND
//  - 3-Kleuren LED:
//    - Common anode aan 5V
//    - 470 Ω weerstanden tussen:
//      - Kathode Rood en collector van T1
//      - Kathode Groen en collector van T2
//      - Kathode Blauw en collector van T3
//    - 10 kΩ weerstanden tussen:
//      - Arduino digitale pin  9 en basis van T1
//      - Arduino digitale pin 10 en basis van T2
//      - Arduino digitale pin 11 en basis van T3
//    - Emitter van T1 aan GND
//    - Emitter van T2 aan GND
//    - Emitter van T3 aan GND

const int Rood   =  9; //PWM pin
const int Groen  = 10; //PWM pin
const int Blauw  = 11; //PWM pin
const int Switch = 13;

const int Knipperaantal = 5;
const int Knippervertraging = 250;

void setup(void){
  pinMode(Switch, INPUT);
  pinMode(Rood,   OUTPUT);
  pinMode(Groen,  OUTPUT);
  pinMode(Blauw,  OUTPUT);
  //Initialiseer de random generator
  randomSeed(analogRead(0));
  Serial.begin(9600);
}

void Kleur(int rood, int groen, int blauw){
  analogWrite(Rood,  rood);
  analogWrite(Groen, groen);
  analogWrite(Blauw, blauw);
}

void Knipper(int rood, int groen, int blauw, int aantal, int vertraging){
  int  Teller;
  
  for (Teller = 0; Teller < aantal; Teller++){
    Kleur(rood, groen, blauw);
    delay(vertraging);
    Kleur(0, 0, 0);
    delay(vertraging);
  }
}

void loop(void){
  bool Cheat;
  int  Wachttijd, WachtStart, VerlopenTijd;
  int  Starttijd, Eindtijd;
  char Reactietijdtekst[17];
  
  //Zet het licht op groen om aan te geven dat de test kan starten
  Kleur(0, 255, 0);
  //Wacht tot de schakelaar is losgelaten
  while (digitalRead(Switch) == HIGH);
  //Gebruik een pseudo ontdendering door 50 ms te wachten
  delay(100);
  //Wacht tot de schakelaar is ingedrukt  
  while (digitalRead(Switch) == LOW);
  //Gebruik een pseudo ontdendering door 50 ms te wachten
  delay(100);
  //Wacht tot de schakelaar is losgelaten
  while (digitalRead(Switch) == HIGH);
  
  //Zet het licht op geel
  Kleur(255, 140, 0);
  delay(1000);
  Kleur(0, 0, 0);
  //Genereer wachttijd tussen 2 en 5 seconden
  Wachttijd = random(2000, 5000);
  //Zet starttijd op basis van interne klok
  WachtStart = millis();
  Cheat = false;
  do{
    if (digitalRead(Switch) == HIGH){
      Cheat = true;
      break;
    }
    VerlopenTijd = millis() - WachtStart;
  } while (VerlopenTijd < Wachttijd);
  //Set het licht op blauw
  Kleur(0, 0, 255);
  Starttijd = millis();
  //Wacht tot de schakelaar wordt ingedrukt
  do{
  } while (digitalRead(Switch) == LOW);
  Eindtijd = millis();
  if (Cheat){
    Knipper(255, 0, 0, Knipperaantal, Knippervertraging);
  } else {
    sprintf(Reactietijdtekst, "%d ms", Eindtijd - Starttijd);
    Serial.println(Reactietijdtekst);
    Knipper(0, 255, 0, Knipperaantal, Knippervertraging);
  }
}

Bovenstaande sketches zijn compleet en werken zonder aanpassingen als ze gekopieerd worden naar de Arduino ontwikkelomgeving versie 1.0.1.

Eerste publicatie op 23 maart 2013

Laatste modificatie op 27 maart 2013