Gegevensuitvoer

Als we meer informatie naar buiten willen brengen dan aan te geven is door een LED aan te sluiten op een digitale output poort van de Arduino, hebben we twee eenvoudige mogelijkheden. De eerste is het versturen van de output via de USB kabel naar het scherm van de PC. Een leuke bijkomstigheid is dat we vanuit de 'Serial Monitor' (na het starten van de sketch kiezen voor "Seriële-monitor" in het menu "Extra" of gebruik Ctrl-Shift-M), ook gegevens naar de Arduino kunnen sturen. In onze projecten gebruiken we slechts een beperkt aantal functies (available, begin, print, println, read). Zie ook de sketch hieronder. Meer informatie is te vinden op arduino.cc. Uiteraard werkt dit alleen als de Arduino via de USB kabel is aangesloten op de PC.

//Dimmen van de on-board LED door software pulsbreedtemodulatie
//
//Aansluitingen
//  PC aansluiten via de USB kabel op de Arduino

const int  Plus = 43; //ASCII code van '+'
const int  Min  = 45; //ASCII code van '-'

const int LedPin = 13;
const int Minimum = 0;
const int Maximum = 20;
int  Niveau = Minimum;

void setup() {                
  pinMode(LedPin, OUTPUT);
  Serial.begin(9600);
}

void loop() {
  byte  Input;
  
  if (Serial.available()){
    Input = Serial.read();
    switch(Input){
      case Plus:
        if (Niveau < Maximum){
          Niveau++;
          Serial.print("Niveau ingesteld op: ");
          Serial.println(Niveau);
        }
        break;
      case Min:
        if (Niveau > Minimum){
          Niveau--;
          Serial.print("Niveau ingesteld op: ");
          Serial.println(Niveau);
        }
        break;
      default:
        Serial.print("Geen geldige input: ");
        Serial.println(Input);
        break;
    }
  }
  digitalWrite(LedPin, HIGH);   // Doe de LED aan
  delay(Niveau);                // Wacht Niveau ms
  digitalWrite(LedPin, LOW);    // Doe de LED uit
  delay(Maximum-Niveau);        // Wacht (Maximum-Niveau) ms
}

De andere mogelijkheid is het gebruik van een eenvoudig LCD display. In onze projecten gebruiken we een LCD puntmatrix module met twee regels van 16 tekens zonder verlichting van Conrad. Let er wel op dat op dit display standaard geen headers gemonteerd zijn. Maar die zijn er gelukkig makkelijk en snel op de solderen op de voor of achterzijde van de printplaat. Wij hebben ervoor gekozen om geen headers maar 'male connectors' te gebruiken. Afhankelijk van de gewenste montage kan gekozen worden uit bijvoorbeeld een haakse of een rechte variant.

Alleen de aansluitingen aan de onderzijde worden gebruikt en de nummering van de aansluitingen staat op de printplaat en is aan de voorzijde van links naar rechts: 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 16, 15. De aansluitingen hebben de volgende betekenis waarbij de grijze aansluitingen in onze projecten niet gebruikt worden:

No. Symbol Function

1 Vss Gnd, 0V

2 Vdd +5V

3 V0 LCD Drive

4 RS Function Select

5 R/W Read/Write

6 E Enable Signal

7 DB0 Data Bus Line 0

8 DB1 Data Bus Line 1

9 DB2 Data Bus Line 2

10 DB3 Data Bus Line 3

11 DB4 Data Bus Line 4

12 DB5 Data Bus Line 5

13 DB6 Data Bus Line 6

14 DB7 Data Bus Line 7

15 A 4.2V for LED

16 K Power Supply for LED 0V

No.	Symbol	Function
1	Vss	Gnd, 0V
2	Vdd	+5V
3	V0	LCD Drive
4	RS	Function Select
5	R/W	Read/Write
6	E	Enable Signal
7	DB0	Data Bus Line 0
8	DB1	Data Bus Line 1
9	DB2	Data Bus Line 2
10	DB3	Data Bus Line 3
11	DB4	Data Bus Line 4
12	DB5	Data Bus Line 5
13	DB6	Data Bus Line 6
14	DB7	Data Bus Line 7
15	A	4.2V for LED
16	K	Power Supply for LED 0V

De V0 aansluiting wordt aangesloten op de slede van een potentiometer die tussen de 5V en de GND staat. Afhankelijk van de stand van de potentiometer kan het display leeg blijven of helemaal zwart zijn. Ergens daartussen is een stand waarin het display goed leesbaar is. Een potentiometer van 10kΩ voldoet bij ons prima.

Onderstaande sketch schrijft de tekst "Hello world" op de eerste regel van het display en "Output" op de tweede regel.

///Eenvoudig voorbeeld voor het gebruik van een LCD display
//
//Aansluitingen van het display
// - Pin  1: aan de GND van de Arduino
// - Pin  2: aan +5V
// - Pin  3: aan slede van 10k potentiometer tussen 5V en GND
// - Pin  4: aan pin 2 van de Arduino
// - Pin  5: aan de GND van de Arduino
// - Pin  6: aan pin 3 van de Arduino
// - Pin 11: aan pin 4 van de Arduino
// - Pin 12: aan pin 5 van de Arduino
// - Pin 13: aan pin 6 van de Arduino
// - Pin 14: aan pin 7 van de Arduino

#include <LiquidCrystal.h>

const int  RS  =  2;
const int  E   =  3;
const int  D4  =  4;
const int  D5  =  5;
const int  D6  =  6;
const int  D7  =  7;

LiquidCrystal lcd(RS, E, D4, D5, D6, D7);

void setup() {
  lcd.begin(16, 2);
  lcd.display();
  lcd.clear();
  lcd.print("Hello world");
  lcd.setCursor(0,1);
  lcd.print("Output");
}

void loop() {
}