Dockhorn Software - Drukschakelaar

Aansluiten van een drukschakelaar

Een schakelaar lijkt wel zo ongeveer de eenvoudigste denkbare component. Zo simpel als het lijkt, is het echter niet. Het indrukken van de schakelaar moet er voor zorgen dat de spanning op een digitale input van 'laag' (0V) naar 'hoog' (5V) gaat. Als de ingang niet is aangesloten is de waarde ongedefinieerd. In onderstaande figuur zorgt de weerstand (R1) ervoor dat de uitgang 'laag' is zolang de schakelaar niet is ingedrukt. Als de schakelaar wordt ingedrukt, staat over de weerstand een spanning van 5V en daarmee is de uitgang 'hoog'.

Voor digitale techniek in combinatie met een klokfrequentie van 16MHz, is er wel een aandachtspunt: het zogenaamde 'denderen' van de schakelaar. Simpel gezegd komt het erop neer dat als we een schakelaar indrukken dat er contact gemaakt wordt, het contact weer kort verbroken wordt en er dan weer contact wordt gemaakt. En dat eventueel meerdere keren. Aangesloten op een digitale input, lijkt het dan alsof de schakelaar meerdere keren wordt ingedrukt en weer wordt losgelaten. In onderstaande sketch kan het door het denderen bij het indrukken van de schakelaar onmogelijk blijken om de code 1, 2, 1 (schakelaar 1, schakelaar 2, schakelaar 1) in te voeren.

//Sketch om de code 1-2-1 te laten controleren ...
// ... en waarbij denderen roet in het eten kan gooien
//
//Aansluitingen
//  - Schakelaar 1 tussen 5V en Arduino Digitaal pin 2
//  - Een weerstand van 10k tussen Arduino Digitaal pin 2 en GND
//  - Schakelaar 2 tussen 5V en Arduino Digitaal pin 3
//  - Een weerstand van 10k tussen Arduino Digitaal pin 3 en GND
//
//Als de schakelaar 1 niet is ingedrukt is pin 2 LOW
//Als de schakelaar 1 is ingedrukt is pin 2 HIGH
//Als de schakelaar 2 niet is ingedrukt is pin 3 LOW
//Als de schakelaar 2 is ingedrukt is pin 3 HIGH

const int S1 =  2;
const int S2 =  3;

void setup(){
   pinMode(S1, INPUT);
   pinMode(S2, INPUT);
   Serial.begin(9600); 
}

void loop(){
   if ((GetSwitch()==1) && (GetSwitch()==2) && (GetSwitch()==1)){
      Serial.println("Code correct");
   } else {
      Serial.println("Code incorrect");
   }
}

int GetSwitch(){
   while (true){
      if (digitalRead(S1) == HIGH){
   //Als schakelaar 1 is ingedrukt ...
         while(digitalRead(S1) == HIGH);
   // ... wacht dan tot de schakelaar wordt losgelaten
         return(1);
      }
      if (digitalRead(S2) == HIGH){
      //Als schakelaar 2 is ingedrukt ...
         while(digitalRead(S2) == HIGH);
      // ... wacht dan tot de schakelaar wordt losgelaten
         return(2);
      } 
   } 
}

De meest zuivere manier om dit te voorkomen is het gebruik van een drukschakelaar die bij het indrukken een contact verbreekt en in ingedrukte stand een ander contact maakt. Bij het loslaten wordt het eerste contact weer gemaakt.

Onderstaande sketch lost het probleem van het denderen van de schakelaar op. Nadelen van deze oplossing zijn wel dat per druktoets twee digitale inputs gebruikt worden en dat de schakelaars duurder zijn dan de druktoetsen met alleen een maakcontact.

//Sketch om een schakelaar te ontdenderen
//
//Aansluitingen
//  - Maakcontact van schakelaar aan Arduino Digitaal pin 2
//  - Een weerstand van 10k tussen Arduino Digitaal pin 2 en 5V
//  - Verbreekcontact van schakelaar aan Arduino Digitaal pin 3
//  - Een weerstand van 10k tussen Arduino Digitaal pin 3 en 5V
//
//Als de schakelaar is ingedrukt is pin 2 LOW en pin 3 HIGH
//Als de schakelaar is losgelaten is pin 2 HIGH en pin 3 LOW 

const int MAAK = 2;
const int VERBREEK = 3;
int  Button;
  
  
void setup(){
  pinMode(MAAK, INPUT);
  pinMode(VERBREEK, INPUT);
  Serial.begin(9600); 
  Button = 0;
}

void loop(){
 
  if ((Button == 0) && (digitalRead(MAAK) == LOW)){
    Serial.println("Schakelaar ingedrukt");
    Button = 1;
  }
  if ((Button == 1) && (digitalRead(VERBREEK) == LOW)){
    Serial.println("Schakelaar los");
    Button = 0;
  }
}

In de projecten maken we gebruik van drukschakelaars met maakcontacten. Om het denderprobleem te omzeilen gebruiken we de 'delay' functie om zolang te wachten dat de schakelaar uitgedenderd zou moeten zijn. Als snel op het indrukken van de schakelaar gereageerd moet worden, komt de 'delay' na de uit te voeren actie. In andere gevallen kan de 'delay' meteen na het indrukken van de schakelaar komen.