Projecten - Badkamerventilator

Badkamerventilatoren zijn er in vele soorten. De eenvoudigste schakel je met de verlichting in en uit. Dan zijn er de ventilatoren met een uitschakelvertraging, soms is die vertraging zelfs nog in te stellen. Tenslotte zijn er nog ventilatoren met een hygrostaat. Deze ventilatoren schakelen boven een in te stellen luchtvochtigheid in en eronder weer uit. Ventilatoren met een hygrostaat zijn wel weer wat duurder en het lastige ervan is dat de lucht in huis in de winter minder vochtig is dan in de zomer. Bij een vaste instelling kan het dus zijn dat de ventilator in de winter niet aangaat en in de zomer niet uit. De oplossing is gelukkig simpel: we meten niet alleen de vochtigheid in de badkamer maar ook in de ruimte van waaruit de lucht wordt aangezogen, bijvoorbeeld de overloop of slaapkamer. Het heeft immers alleen zin om de ventilator te laten draaien als de aangevoerde lucht minder vocht bevat dan de lucht in de badkamer. Aangezien de lucht in de badkamer warmer kan zijn, is het vergelijken van de relatieve vochtigheid niet zo'n goed idee. In plaats daarvan zouden we de hoeveelheid water per kubieke meter lucht moeten vergelijken. Een andere optie, en daarvoor hebben we hier gekozen, is het vergelijken van de dauwtemperatuur binnen en buiten de badkamer. Zolang de dauwtemperatuur in de badkamer hoger is dan de dauwtemperatuur erbuiten, heeft het zin de ventilator aan te zetten.

We hebben de schakeling uitgebreid met twee LED's die gaan branden als de communicatie met de sensoren niet goed verloopt. De LED's zijn niet nodig voor de werking van het systeem maar kunnen wel handig zijn voor het vaststellen van evenetuele problemen.

Schakeling

Voor de schakeling maken we gebruik van een ongemonteerd relais maar natuurlijk kan gebruik worden gemaakt van een gemonteerd relais SRD-05VDC-SL-C. In de achtergrondinformatie leest u hierover meer.

Onderdelen

Component	Type	Aantal
Sensor1, Sensor 2	DHT11	2
R1, R2, R5	10 kΩ	3
Ventilator	Zonder hygrostaat en timer	1
Relais 1	HF3FA	1
T1	BC 549C	1
D3	1N4004	1
Optioneel
R3, R4	470 Ω	2
D1, D2	Rode 3mm LED	2

Sketch

In de sketch berekenen we bij het starten van het programma het verschil tussen de dauwtemperatuur binnen en buiten de badkamer. Als het verschil toeneemt, schakelen we de ventilator in, komt het verschil weer op de oorspronkelijke waarde dan schakelen we de ventilator weer uit. We hebben hierbij wel een kleine marge ingebouwd alsmede gezorgd dat het relais niet gaat "klapperen". Als het verschil tussen dauwtemperatuur in de badkamer en erbuiten meer dan 4°C is toegenomen, schakelen we de ventilator in. We schakelen de ventilator pas weer uit als het verschil minder dan 2°C groter is dan bij het starten. Het is dus van belang de deur van de badkamer geruime tijd open te zetten voordat het programma wordt gestart. De absolute luchtvochtigheid zal dan binnen en buiten de badkamer aan elkaar gelijk zijn.

Bij het starten van de sketch gaan de twee LED's aan. Pas als de communicatie met beide sensoren goed is verlopen, gaan de LED's uit. Als er een fout optreedt in de communicatie met één van de sensoren gaat de bijbehorende LED aan en wordt de ventilator uitgeschakeld. De LED gaat weer uit als van de sensor de metingen correct is ontvangen.

//Sketch voor de badkamervenilator
//
//Aansluitingen
//  - Sensor binnen badkamer aan 5V en GND
//  - Sensor buiten badkamer aan 5V en GND
//  - 10k weerstand tussen 5V en Sensorpin van binnensensor
//  - 10k weerstand tussen 5V en Sensorpin van buitensensor
//  - Sensorpin van binnensensor aan Arduino pin 10
//  - Sensorpin van buitensensor aan Arduino pin 11
//  - Arduino pin 12 aan input van relais

#include "DHT.h"

#define DHT_IN  10
#define DHT_UIT 11
#define Relais  12

//Omdat de sensoren niet dezelfde waarden opleveren slaan we 
//bij de initialisatie het verschil in de berekende
//dauwtemperatuur op in de variabele DeltaTemp.
int     DeltaTemp;
boolean FanOn;

#define DHTTYPE DHT11   // DHT 11 
//#define DHTTYPE DHT22   // DHT 22  (AM2302)
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

DHT Dht_In(DHT_IN,  DHTTYPE);
DHT Dht_Uit(DHT_UIT, DHTTYPE);

const double A = 17.27;
const double B = 237.7;

double Gamma(double temp, double humidity){
  return( (A * temp) / (B + temp) + log(humidity / 100) );
}

int DewTemperature(float temp, float humidity){
  double  GammaValue;
  
  GammaValue = Gamma( (double)temp, (double)humidity );
  return((int)((B * GammaValue) / (A - GammaValue)));
}

void ReadSensor(DHT sensor, float *h, float *t){
  *h = sensor.readHumidity();
  *t = sensor.readTemperature();
}

void setup() {
  int     DauwtemperatuurBinnen;
  int     DauwtemperatuurBuiten;

  float     H, T;
  //Schakel ventilator uit
  pinMode(Relais, OUTPUT);
  digitalWrite(Relais, LOW);
  FanOn = false;
  //Wacht op initialisatie van de sensoren
  delay(2000);
  Dht_In.begin();
  Dht_Uit.begin();

  ReadSensor(Dht_In, &H, &T);
  DauwtemperatuurBinnen = DewTemperature(T, H);
  ReadSensor(Dht_Uit, &H, &T);
  DauwtemperatuurBuiten = DewTemperature(T, H);

  DeltaTemp = DauwtemperatuurBinnen - DauwtemperatuurBuiten;
}

void loop() {
  float H;
  float T;
  float DT_in, DT_uit;

  ReadSensor(Dht_In, &H, &T);
  DT_in = DewTemperature(T, H);
  
  // check dat de waarden valide zijn
  if (isnan(T) || isnan(H)) {
    delay(1000);
  } else {

    ReadSensor(Dht_Uit, &H, &T);
    DT_uit = DewTemperature(T, H);
  
    // check dat de waarden valide zijn
    if (isnan(T) || isnan(H)) {
      delay(1000);
    }
    if ( (DT_in - DT_uit) > (DeltaTemp + 4)){
      if (!FanOn){
        digitalWrite(Relais, HIGH);
        FanOn = true;
      }
    }
    if ( (DT_in - DT_uit) <= (DeltaTemp + 2)){
      if (FanOn){
        digitalWrite(Relais, LOW);
        FanOn = false;
      } 
    }
  }
  delay(10000);
}

Van deze sketch hebben we ook een variant voor de ATtiny85 gemaakt. Deze maakt gebruik van een kleinere library dan de algemene DHT-libary die ook bruikbaar is voor de DHT21 en DHT22. Daardoor zou de gecompileerde sketch ook in de ATtiny45 moeten passen. De librarybestanden die wij gebruiken zijn dht11.h en dht11.cpp. Deze bestanden moeten binnen de Sketch map in de map "libary/dht11" komen te staan. Voor meer informatie over het toevoegen van libraries staat op www.arduino.cc.

//Sketch voor de badkamervenilator
//
//Aansluitingen
//  - Sensor binnen badkamer aan 5V en GND
//  - Sensor buiten badkamer aan 5V en GND
//  - 10kΩ weerstand tussen 5V en Sensorpin van sensor binnen badkamer
//  - 10kΩ weerstand tussen 5V en Sensorpin van sensor buiten badkamer
//  - ATTiny85 pin 2 aan sensorpin van sensor buiten badkamer
//  - ATTiny85 pin 3 aan error led anode voor sensor buiten badkamer
//  - ATTiny85 pin 5 aan input van relais
//  - ATTiny85 pin 6 aan sensorpin van sensor binnen badkamer
//  - ATTiny85 pin 7 aan error led anode voor sensor binnen badkamer
//  - 470Ω weerstand tussen de led kathode voor sensor buiten badkamer en GND
//  - 470Ω weerstand tussen de led kathode voor sensor binnen badkamer en GND

#define Relais   0    //ATTiny85 digital 0 = pin 5
#define DHT_IN   1    //ATTiny85 digital 1 = pin 6
#define ERR_IN   2    //ATTiny85 digital 2 = pin 7
#define DHT_UIT  3    //ATTiny85 digital 3 = pin 2
#define ERR_UIT  4    //ATTiny85 digital 4 = pin 3

#include <dht11.h>

//Omdat de sensoren niet dezelfde waarden opleveren slaan we bij de 
//initialisatie het verschil in de berekende dauwtemperatuur op in
//de variabele DeltaTemp.
int     DeltaTemp;
boolean FanOn;

dht11 DHT11;

int DewTemperature(double temperature, double humidity){
  const double A = 17.271;
  const double B = 237.7;
  double Temporary;
  
  Temporary = (A * temperature) / (B + temperature) + log(humidity / 100);
  return((int)((B * Temporary) / (A - Temporary)));
}


void setup() {
  int     DauwtemperatuurBinnen;
  int     DauwtemperatuurBuiten;
  int     Status;
  double  Humidity;
  double  Temperature;

  //Wacht op initialisatie van de sensoren
  delay(2000);
  //Schakel ventilator uit en zet error LED's aan
  pinMode(Relais, OUTPUT);
  digitalWrite(Relais, LOW);
  pinMode(ERR_IN, OUTPUT);
  digitalWrite(ERR_IN, HIGH);
  pinMode(ERR_UIT, OUTPUT);
  digitalWrite(ERR_UIT, HIGH);
  FanOn = false;
  do{
    digitalWrite(ERR_IN, HIGH);
    digitalWrite(ERR_UIT, HIGH);
    do{
      Status = DHT11.read(DHT_IN);
      if (Status == DHTLIB_OK){
        Humidity = (double)DHT11.humidity;
        Temperature = (double)DHT11.temperature;
        DauwtemperatuurBinnen = DewTemperature(Temperature, Humidity);
        digitalWrite(ERR_IN, LOW);
      } else {
        delay(1000);
      }
    } while (Status != DHTLIB_OK);
    Status = DHT11.read(DHT_UIT);
    if (Status == DHTLIB_OK){
      Humidity = (double)DHT11.humidity;
      Temperature = (double)DHT11.temperature; 
      DauwtemperatuurBuiten = DewTemperature(Temperature, Humidity);
      digitalWrite(ERR_UIT, LOW);
    } else {
      delay(1000);
    }
  } while (Status != DHTLIB_OK);
  DeltaTemp = DauwtemperatuurBinnen - DauwtemperatuurBuiten;
  delay(1000);
}

void loop(){
  double Humidity;
  double Temperature;
  double DewTemperature_in;
  double DewTemperature_uit;
  int    Status;
  
  if((Status = DHT11.read(DHT_IN)) != DHTLIB_OK){
    digitalWrite(ERR_IN, HIGH);
    digitalWrite(Relais, LOW);
    FanOn = false;
    delay(100);
  } else {
    digitalWrite(ERR_IN, LOW);
    Humidity = DHT11.humidity;
    Temperature = DHT11.temperature;
    DewTemperature_in = DewTemperature(Temperature, Humidity);
  
    if((Status = DHT11.read(DHT_UIT)) != DHTLIB_OK){
      digitalWrite(ERR_UIT, HIGH);
      digitalWrite(Relais, LOW);
      FanOn = false;
      delay(100);
    } else {
      digitalWrite(ERR_UIT, LOW);
      Humidity = DHT11.humidity;
      Temperature = DHT11.temperature;
      DewTemperature_uit = DewTemperature(Temperature, Humidity);

      if ( (DewTemperature_in - DewTemperature_uit) > (DeltaTemp + 4)){
        if (!FanOn){
          digitalWrite(Relais, HIGH);
          FanOn = true;
        }
      }
      if ( (DewTemperature_in - DewTemperature_uit) <= (DeltaTemp + 2)){
        if (FanOn){
          digitalWrite(Relais, LOW);
          FanOn = false;
        } 
      }
    }
  }
  delay(10000);
}

Bovenstaande sketches zijn compleet en werken zonder aanpassingen als ze gekopieerd worden naar de Arduino ontwikkelomgeving.

Gepubliceerd op 24 april 2013