Projecten - Geheugentest

De uitdaging die dit project biedt, is het onthouden en reproduceren van een reeks kleuren. Als de LED wit licht geeft, begint het spel door op één van de schakelaars te drukken. Het begint lekker makkelijk met een reeks van één element. Druk achtereenvolgens op de schakelaar met de kleur van de elementen van de reeks. Zolang de reeks correct wordt nagespeeld, wordt de reeks met een nieuw element uitgebreid. Is de reeks niet correct dan wordt een nieuwe reeks gegenereerd en begint het weer met één element.

Schakeling

Onderdelen

Component	Type	Aantal
R1, R2, R3	470 Ω	3
R4, R5, R6	10 kΩ	3
D1, D2, D3	Driekleuren LED	1
T1, T2, T3	Transistor BC549C	3
S1	Rode drukschaklaar	1
S2	Groene drukschaklaar	1
S3	Blauwe drukschaklaar	1

Sketch

In onderstaande sketch maken we gebruik van de interne pull-up weerstanden van de Atmega chip op de Arduino. In plaats van de pinMode INPUT gebruiken we nu INPUT_PULLUP. Het enige wat we nu hoeven doen is de input via een schakelaar met de GND verbinden. Let er wel op dat de waarde van de input nu HIGH is al de schakelaar niet is ingedrukt en LOW als de schakelaar wel is ingedrukt.

//Sketch voor een eenvoudige geheugentest
//
// Aansluitingen:
//  - Rode drukschakelaar tussen Arduino digitale pin 10 en GND
//  - Groene drukschakelaar tussen Arduino digitale pin 11 en GND
//  - Blauwe drukschakelaar tussen Arduino digitale pin 12 en GND
//  - Emitters van T1, T2 en T3 aan GND
//  - 10 kΩ weerstanden tussen:
//    - Arduino digitale pin 2 en basis van T1
//    - Arduino digitale pin 3 en basis van T2
//    - Arduino digitale pin 4 en basis van T3
//  
//  - Driekleuren LED:
//    - Common anode aan 5V
//    - 470 Ω weerstanden tussen:
//      - Kathode rode   LED en collector van T1
//      - Kathode groene LED en collector van T2
//      - Kathode blauwe LED en collector van T3

const int MaxLevel = 20;
int       Sequence[MaxLevel];

const int NumberOfLeds = 3;

const int RLedPin = 2;      //Rode LED
const int GLedPin = 3;      //Groene LED
const int BLedPin = 4;      //Blauwe LED
const int LedPin[NumberOfLeds] = {RLedPin, GLedPin, BLedPin};

const int RButtonPin = 10;  //Rode schakelaar
const int GButtonPin = 11;  //Groene schakelaar
const int BButtonPin = 12;  //Blauwe schakelaar
const int ButtonPin[NumberOfLeds] = {RButtonPin, GButtonPin, BButtonPin};

int       Level;

void setup(void){
  int  Index;
  
  for (Index = 0; Index < NumberOfLeds; Index++){
    pinMode(LedPin[Index], OUTPUT);
    digitalWrite(LedPin[Index], LOW);
    pinMode(ButtonPin[Index], INPUT_PULLUP);
  }
  pinMode(13, OUTPUT);
  digitalWrite(13, 0);
  randomSeed(analogRead(0));
  Level = 1;
}

void loop(void){
  int  Switch;
  int  Index;

  for (Index = 0; Index < NumberOfLeds; Index++){
    digitalWrite(LedPin[Index], HIGH);
  }
  while (ReadSwitch() == -1){
    delay(50);
  }
  for (Index = 0; Index < NumberOfLeds; Index++){
    digitalWrite(LedPin[Index], LOW);
  }
  while (ReadSwitch() != -1){
    delay(50);
  }
  for (Index=0; Index < MaxLevel; Index++){
    Sequence[Index] = random(0, NumberOfLeds);
    Light(LedPin[Sequence[Index]], 100);
    delay(500);
  }
  delay(2000);
  Level = 1;
  while (Level <= MaxLevel){
    for (Index = 0; Index < Level; Index++){
      Light(LedPin[Sequence[Index]], 100);
      delay(500);
    }
    Index = 0;
    while (Index < Level){
      if ((Switch = ReadSwitch()) != -1){
        Light(LedPin[Switch], 50);
        while (ReadSwitch() != -1){
          delay(100);
        }
        if (Switch == Sequence[Index]){
          Index++;
        } else {
          for (Index=0; Index < 10; Index++){
            Light(RLedPin, 100);
            delay(100);
          }
          delay(2000);
          Level = 0;
        }
      }
    }
    Level++;
    if (Level > 1){
      for (Index=0; Index < 10; Index++){
        Light(GLedPin, 100);
        delay(100);
      }
    }
    delay(2000);
    if (Level > MaxLevel){
      for (Index=1; Index < 50; Index++){
        for (int Led=0; Led < 3; Led++){
          Light(LedPin[Led], 50); 
        }
      }
      delay(2000);
    }
  }
}

int ReadSwitch(void){
  int  Button;
  int  PressedButton = -1;
  
  for (Button=0; Button<NumberOfLeds; Button++){
    if (digitalRead(ButtonPin[Button]) == LOW){
      PressedButton = Button;
    }
  }
  return(PressedButton);
}

void Light(int ledPin, int duration){
  digitalWrite(ledPin, HIGH);
  delay(duration);
  digitalWrite(ledPin, LOW);
}

Bovenstaande sketch is compleet en werkt zonder aanpassingen als deze gekopieerd wordt naar de Arduino ontwikkelomgeving versie 1.0.1.

Eerste publicatie op 25 april 2013

Laatste modificatie op 25 april 2013