Projecten - Dobbelsteen

De kans dat je geen dobbelsteen in huis hebt, maar wel alle componenten voor dit project is klein. Maar het gaat natuurlijk niet alleen om het dobbelen maar ook om het maken van deze elektronische dobbelsteen. De uitdaging van dit project was om het aantal inputs en outputs op maximaal vijf te houden, zodat het project ook in de ATTiny geprogrammeerd kan worden. Dat lukt omdat zes van de zeven LED's drie paren vormen. Beide LED's van ieder paar zijn gelijktijdig aan en gelijktijdig uit.

Schakeling

Onderdelen

Component	Type	Aantal
R1 .. R7	470 Ω	7
R8 .. R11	10 kΩ	4
D1 .. D7	Rode LED 5mm	7
T1 .. T4	Transistor BC549C	4
S1	Rode drukschaklaar	1

Sketch

In onderstaande sketch maken we gebruik van de interne pull-up weerstanden van de Atmega chip op de Arduino. In plaats van de pinMode INPUT gebruiken we nu INPUT_PULLUP. Het enige wat we nu hoeven doen is de input via een schakelaar met de GND verbinden. Let er wel op dat de waarde van de input nu HIGH is als de schakelaar niet is ingedrukt en LOW als de schakelaar wel is ingedrukt.

//  AAA    L       EEEEE    AAA
// A   A   L       E       A   A
// A   A   L       E       A   A
// AAAAA   L       EEEE    AAAAA
// A   A   L       E       A   A
// A   A   L       E       A   A
// A   A   LLLLL   EEEEE   A   A

// Aansluitingen:
//  - Rode drukschakelaar tussen Arduino digitale pin 8 en GND
//  - Emitters van T1, T2, T3 en T4 aan GND
//  - 10 kΩ weerstanden tussen:
//    - Arduino digitale pin 2 en basis van T1
//    - Arduino digitale pin 3 en basis van T2
//    - Arduino digitale pin 4 en basis van T3
//    - Arduino digitale pin 5 en basis van T4
//  - LEDs:
//    - Anoden aan 5V
//    - 470Ω weerstanden tussen:
//      - cathode van D1 en de collector van T1
//      - cathode van D2 en de collector van T2
//      - cathode van D3 en de collector van T3
//      - cathode van D4 en de collector van T4
//      - cathode van D5 en de collector van T3
//      - cathode van D6 en de collector van T2
//      - cathode van D7 en de collector van T1 


const int NumGroups = 4;
const int GroupPin[NumGroups] = {2, 3, 4, 5};
const int SwitchPin = 8;

void setup(){
  int  I;

  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);

  for (I = 0; I < NumGroups; I++){
    pinMode(GroupPin[I], OUTPUT);
    digitalWrite(GroupPin[I], LOW);
  }

  pinMode(SwitchPin, INPUT_PULLUP);

  randomSeed(analogRead(0));
}

void loop(){
  int  Eyes;
  int  I;

  if (digitalRead(SwitchPin) == LOW){
    Clean();
    while (digitalRead(SwitchPin) == LOW){
      Eyes = random(1, 7);
    }
    Throw( Eyes );
    delay(2000);
  }  
}

void Clean(void){
  int  I;
  
  for (I = 0; I < NumGroups; I++){
    digitalWrite(GroupPin[I], LOW);
  }
}

void Throw(int eyes){
  int  I;
  int  Eyes;
  
  for (I=0; I<50; I++){
    Eyes = random(1, 7);
    Show(Eyes);
    delay(20);
    Clean();
  }
  Clean;
  Show(eyes);
}

void Show(int eyes){
  digitalWrite(GroupPin[0], (eyes != 1) ? HIGH : LOW);
  digitalWrite(GroupPin[1], (eyes > 3) ? HIGH : LOW);
  digitalWrite(GroupPin[2], (eyes == 6) ? HIGH : LOW);
  digitalWrite(GroupPin[3], (eyes % 2 == 1) ? HIGH : LOW);
}

Dobbelsteen voor ATTiny

Voor de ATTiny45 of ATTiny85 gebruiken we het volgende schema:

In de sketch moeten de aansluitingen worden aagepast:

//  AAA    L       EEEEE    AAA       TTTTT   III   N   N   Y   Y
// A   A   L       E       A   A        T      I    N   N   Y   Y
// A   A   L       E       A   A        T      I    NN  N    Y Y
// AAAAA   L       EEEE    AAAAA        T      I    N N N     Y
// A   A   L       E       A   A        T      I    N  NN     Y
// A   A   L       E       A   A        T      I    N   N     Y
// A   A   LLLLL   EEEEE   A   A        T     III   N   N     Y

// Aansluitingen:
//  - Rode drukschakelaar tussen ATTiny digitale pin 0 en GND
//  - Emitters van T1, T2, T3 en T4 aan GND
//  - 10 kΩ weerstanden tussen:
//    - ATTiny digitale pin 1 en basis van T1
//    - ATTiny digitale pin 2 en basis van T2
//    - ATTiny digitale pin 3 en basis van T3
//    - ATTiny digitale pin 4 en basis van T4
//  - LEDs:
//    - Anoden aan 5V
//    - 470Ω weerstanden tussen:
//      - cathode van D1 en de collector van T1
//      - cathode van D2 en de collector van T2
//      - cathode van D3 en de collector van T3
//      - cathode van D4 en de collector van T4
//      - cathode van D5 en de collector van T3
//      - cathode van D6 en de collector van T2
//      - cathode van D7 en de collector van T1 


const int NumGroups = 4;
const int GroupPin[NumGroups] = {1, 2, 3, 4};
const int SwitchPin = 0;

void setup(){
  int  I;

  for (I = 0; I < NumGroups; I++){
    pinMode(GroupPin[I], OUTPUT);
    digitalWrite(GroupPin[I], LOW);
  }

  pinMode(SwitchPin, INPUT_PULLUP);

  randomSeed(analogRead(0));
}

void loop(){
  int  Eyes;
  int  I;

  if (digitalRead(SwitchPin) == LOW){
    Clean();
    while (digitalRead(SwitchPin) == LOW){
      Eyes = random(1, 7);
    }
    Throw( Eyes );
    delay(2000);
  }  
}

void Clean(void){
  int  I;
  
  for (I = 0; I < NumGroups; I++){
    digitalWrite(GroupPin[I], LOW);
  }
}

void Throw(int eyes){
  int  I;
  int  Eyes;
  
  for (I=0; I<50; I++){
    Eyes = random(1, 7);
    Show(Eyes);
    delay(20);
    Clean();
  }
  Clean;
  Show(eyes);
}

void Show(int eyes){
  digitalWrite(GroupPin[0], (eyes != 1) ? HIGH : LOW);
  digitalWrite(GroupPin[1], (eyes > 3) ? HIGH : LOW);
  digitalWrite(GroupPin[2], (eyes == 6) ? HIGH : LOW);
  digitalWrite(GroupPin[3], (eyes % 2 == 1) ? HIGH : LOW);
}

Bovenstaande sketches zijn compleet en werken zonder aanpassingen als deze gekopieerd worden naar de Arduino ontwikkelomgeving versie 1.0.1.

Eerste publicatie op 23 februari 2014

Laatste modificatie op 23 februari 2014